Les formulaires

Les contrôles d’un formulaire

Textbox

Pour créer la zone de saisie du nom :

• Cliquer sur l’icône de la boîte à outils(Affichage/Boîte à outils)
• Dessiner la zone de saisie dans le formulaire
• Définir le nom de la zone de saisie dans la fenêtre Propriétés(nom)

Label

Pour créer le libellé Nom :

• Cliquer sur l’icône de la boîte à outils
• Frapper le libellé Nom

Pour créer le menu déroulant Service :

Pour alimenter un ComboBox ou une ListBox, on spécifie dans la propriété RowSource

• le champ de la liste (B2:B5)
• ou le nom du champ (maListeSimple). Pour gérer les ajouts, le nom de champ peut être dynamique
  =DECALER($B$2;;;NBVAL($B:$B)-1)

La propriété RowSource peut être alimentée par VBA

Private Sub UserForm_Initialize()
  Me.ComboBox1.RowSource = "B2:B" & [B65000].End(xlUp).Row
  'Me.ComboBox1.RowSource = "Feuil2!B2:B5" ' autre feuille
  'Me.ComboBox1.RowSource = "Feuil2!B2:B" & Sheets("Feuil2").[B65000].End(xlUp).Row
  'Me.ComboBox1.RowSource = "liste4" ' nom de champ
End Sub

Private Sub UserForm_Initialize()
  Me.Service.List = Array("Etudes", "Informatique", "Marketing", "Production")
  Me.Ville.List = Array("Boulogne", "Lyon", "Paris", "Versailles")
End Sub

Si la liste est dans un autre classeur ouvert

Me.ComboBox1.RowSource = "'[ClasseurSource.xls]Feuil1'!A2:A10"
Me.ComboBox1.RowSource = "'[ClasseurSource.xls]Feuil1'!LaListe"

Récupération du choix :

Private Sub ComboBox1_Change()
  Me.TextBox1 = Me.ComboBox1.Value
End Sub

Positionnement sur le premier élément de la liste

Private Sub UserForm_Initialize()
   Me.ComboBox1.ListIndex = 0 "positionne sur le premier élément
End Sub

Case à cocher

Une case à cocher returne la valeur VRAI ou FAUX

Pour obtenir OUI ou NON, utiliser la fonction ci-dessous.

Function OuiNon(valeur)
  OuiNon = IIf(valeur, "Oui", "Non")
End Function

Groupe d’options civilité

• Dessiner un cadre avec
• Lenommer civilité

• Dessiner des cases d'options à l'intérieur du cadre

Pour connaître l'option choisie dans un groupe, utiliser une boucle For Each x In Groupe.Controls.

Sur l'exemple, on récupère le libellé de l'option (propriété Caption)

Private Sub B_ok_Click()
  temp = ""
  For Each c In Me.Civilité.Controls
     If c.Value Then temp = c.Caption
  Next c
  MsgBox temp 
End Sub

Afficher le formulaire

Show vbModal ou vbModeless

• Le nommer F_création_simple
• Créer une macro dans un module

Sub appel_Simple()
  F_création_simple.Show
End Sub

Créer un bouton avec la barre d’outils Formulaires et lui affecter la macro

Clic-droit/Affecter une macro

Bouton fin

Unload formulaire

Private Sub B_fin_Click()
  Unload Me
End Sub

Limiter le choix du service à la liste

Positionner la propriété MatchRequery à true

Définir la position d’affichage du formulaire

Positionner la propriété StartUpPosition à Manual puis définir les valeurs des propriétés Left et Top

Ordre de saisie

La commande Affichage / Ordre de tabulation permet de définir l’ordre de saisie.

Initialisation du formulaire

Pour initialiser les menus déroulants avec l'événement Initialize du formulaire:

Transfert des zones saisies dans la feuille de calcul

• Créer un bouton
• Le nommer B_validation
• Double-clic sur le bouton

Private Sub b_validation_Click()
   '--- Contrôles
   If Me.nom = "" Then
      MsgBox "Saisir un nom!"
      Me.nom.SetFocus
      Exit Sub
   End If
   If Me.Salaire = "" Then
      MsgBox "Saisir un Salaire!"
      Me.nom.SetFocus
      Exit Sub
   End If
   '-- Date?
   If Not IsDate(Me.date_naissance) Then
      MsgBox "Saisir une date!"
      Me.date_naissance = ""
      Me.date_naissance.SetFocus
      Exit Sub
   End If
   If Not IsNumeric(Me.Salaire) Then
      MsgBox "Saisir du num!"
      Me.Salaire = ""
      Me.Salaire.SetFocus
      Exit Sub
   End If
   '--- Positionnement dans la base
   [A65000].End(xlUp).Offset(1, 0).Select
   '--- Transfert Formulaire dans BD
   ActiveCell.Offset(0, 1).Value = Application.Proper(Me!nom)
   ActiveCell.Offset(0, 2).Value = Application.Proper(Me!prenom)
   ActiveCell.Offset(0, 3).Value = OuiNon(Me.Marié)
   ActiveCell.Offset(0, 4).Value = CVDate(Me.date_naissance)
   ActiveCell.Offset(0, 5).Value = Me.Service
   ActiveCell.Offset(0, 6).Value = Me.Ville
   ActiveCell.Offset(0, 7).Value = CDbl(Me.Salaire)
   '-- Civilité
   temp = ""
   For Each c In Me.Civilité.Controls
     If c.Value = True Then
       temp = c.Caption
     End If
   Next c
   ActiveCell.Value = temp
   '--
   nettoie
End Sub

Sub nettoie()
  Me.prenom = ""
  Me.nom = ""
  Me.date_naissance = ""
  Me.Service = ""
  Me.Ville = ""
  Me.Salaire = ""
  For Each c In Me.Civilité.Controls
    c.Value = False
  Next c
  Me.Marié = False
End Sub

Private Sub b_fin_Click()
  Unload Me
End Sub

Vérification doublons

Ajouter dans la validation:

  Set result = Range("A9:A10000").Find(What:=Me.nom, LookIn:=xlValues, lookat:=xlWhole)
   If Not result Is Nothing Then
      MsgBox "Existe déjà"
      Exit Sub
   End If