Index

Fonction Decaler()
Liste dynamique
Tableau croisé dynamique
Graphique dynamique
Champ dynamique flottant

Decaler(référence,décalageNbLignes;décalageNbColonnes;hauteur;largeur)

La fonction Decaler() permet de définir un champ de largeur et de hauteur variable.

Sur cet exemple, onveut calculer la somme des n premiers mois. Le nombre de mois est dans la cellule D2.

=SOMME(DECALER(B2;0;0;D2;1))

Liste déroulante dynamique

- Sélectionner B2
- Données/Validation
- Choisir Liste
- Cliquer dans Source

=DECALER($F$2;0;0;NBVAL($F:$F)-1)

On peut également créer un nom de champ dynamique avec Insertion/Nom/Définir

-Insertion/Nom/Définir
-MaListe
=DECALER($F$2;0;0;NBVAL($F:$F)-1)

Dans la source de la liste:

=MaListe

Le champ à imprimer contient des lignes vides

Créer un nom de champ dynamique:

-Insertion/Nom/Définir
-Zone_d_impression
=DECALER($A$1;;;MAX(SI($A$2:$E$1000<>"";LIGNE($A$2:$E$1000);0));5)

Tableau croisé dynamique

On ne peut pas créer de groupes avec des cellules vides dans la BD.
Avec un champ dynamique, on peut ajouter des lignes dans la BD, le champ du TCD s'adapte.

1-Nommer la base
-Sélectionner la base
-Créer un nom de champ avec la commande Insertion/Nom/Définir
-Mabd
=DECALER($A$1;0;0;NBVAL($A:$A);6)

2- Lors de la création du TCD, spécifier le nom de champ

Graphique dynamique

On veut que le graphique s'agrandisse au fur et à mesure que des mois sont ajoutés.

1 -Créer le graphe
2- Créer des noms de champs dynamqiues avec Insertion/Nom/Définir

Mois: =DECALER($A$2;0;0;NBVAL($A:$A)-1)
Ca: =DECALER($B$2;0;0;NBVAL($B:$B)-1)

3-Sélectionner le graphe:

Dans la barre de formule, remplacer les numéros de cellules par les noms Mois et CA

=SERIE(GrapheDyn!$B$1;'jb-GraphiqueDynamique.xls'!Mois;'jb-GraphiqueDynamique.xls'!ca;1)

Champ dynamique flottant

Si la BD est succeptiple d'être déplacée:

-Nommer la première cellule de la BD (début par exemple)
-Créer un nom de champ dynamique BDF
=DECALER(début;;;NBVAL(INDIRECT(ADRESSE(LIGNE(début);COLONNE(début))&":"&
      ADRESSE(65000;COLONNE(début))));4)